datos.iepnb.es

Query Examples

The following example find all species that contain 'canis' in their scientific name

 

PREFIX plinian:<http://datos.iepnb.es/def/pliniancore#>
PREFIX darwin: <http://rs.tdwg.org/dwc/terms/>
select
DISTINCT ?TaxonRecordID ?ScientificName from <http://datos.iepnb.es/graph/pliniancore> where
{?TaxonRecord plinian:hasHierarchy ?Taxon .
?TaxonRecord plinian:TaxonRecordID ?TaxonRecordID .
OPTIONAL{?Taxon darwin:scientificName ?ScientificName} .
filter contains(lcase(?ScientificName),'canis')}

 

Run query

 

Get detailed information about the Taxon '11627 (Canis lupus Linnaeus, 1758)'

 

PREFIX pl:<http://datos.iepnb.es/def/pliniancore#>
PREFIX dw: <http://rs.tdwg.org/dwc/terms/>
select distinct * from <http://datos.iepnb.es/graph/pliniancore>
where {{
?TR pl:TaxonRecordID '11627'.
OPTIONAL{?TR pl:FullDescriptionUnstructured ?FuDeUn}.
?TR pl:hasHierarchy ?b .
OPTIONAL{?b dw:scientificName ?ScNa}.
OPTIONAL{?b dw:higherClassification ?HiCl}.
OPTIONAL{?b dw:taxonRank ?Rank}.
OPTIONAL{?b dw:verbatimTaxonRank ?VeTa}.
OPTIONAL{?b dw:scientificNameAuthorship ?ScNA}.
OPTIONAL{?b dw:taxonRemarks ?TaRe}.
OPTIONAL{?b dw:class ?Class}.
OPTIONAL{?b dw:phylum ?Phylum}.
OPTIONAL{?b dw:order ?Order}.
OPTIONAL{?b dw:family ?Family}.
OPTIONAL{?b dw:genus ?Genus}.
OPTIONAL{?b dw:subgenus ?SubGenus}.
OPTIONAL{?b dw:specificEpithet ?SpEp}.
OPTIONAL{?b dw:infraspecificEpithet ?InSpEp}.
OPTIONAL{?b dw:group ?Group}.
OPTIONAL{?b dw:kingdom ?Kingdom}.
OPTIONAL{?b dw:taxonomicStatus ?TaxonomicStatus}. }
UNION {
select * {
?TR pl:TaxonRecordID '11627'.
?TR pl:hasMeasurement ?Ms.
OPTIONAL{?Ms dw:measurementType ?MeTy }.
OPTIONAL{?Ms pl:AppliesTo ?AppliesTo }.
OPTIONAL{?Ms pl:Literal ?Literal }.
OPTIONAL{?Ms dw:measurementValue ?MeaV }.
OPTIONAL{?Ms dw:measurementAccuracy ?MeAcc}.
OPTIONAL{?Ms dw:measurementDeterminedDate ?MeaDD }.
OPTIONAL{?Ms dw:measurementRemarks ?MeaRe }.
OPTIONAL{?Ms pl:measurementUnit ?MeaUn }. }
order by ?MeTy ?AppliesTo ?MeAcc ?Literal }
UNION {
?TR pl:TaxonRecordID '11627'.
?TR pl:hasVernacularName ?VN.
?VN pl:Name ?VerName.
?VN pl:Language ?VerLang. }
UNION {
?TR pl:TaxonRecordID '11627'.
?TR pl:hasDistribution ?Ds.
OPTIONAL{?Ds pl:Distribution_Type ?DisT}.
OPTIONAL{?Ds pl:DistributionScope ?DisCp}.
OPTIONAL{?Ds pl:DistributionScopeType ?DsCT}.
OPTIONAL{?Ds pl:DistributionUnstructured ?DisUn}.
OPTIONAL{?Ds pl:GeographicEntity ?Ge}.
OPTIONAL{?Ds pl:temporalCoverage ?Tc}. }
UNION {
?TR pl:TaxonRecordID '11627'.
?TR pl:hasCollection ?Co.
OPTIONAL{?Co pl:CollectionDescription ?ColDs}.
OPTIONAL{?Co pl:Country_txt ?Country_txt}.
OPTIONAL{?Co pl:Year ?Year}. }
UNION {
?TR pl:TaxonRecordID '11627'.
?TR pl:hasInvasiveness ?In.
OPTIONAL{?In pl:InvasivenessUnstructured ?InvUn}.
OPTIONAL{?In pl:Route ?Route}.
OPTIONAL{?In pl:origin ?origin}.
OPTIONAL{?In pl:vector ?vector}. }
UNION {
SELECT distinct ?ii,
?LegN, group_concat(distinct ?LegR;separator=', ') as ?LegR, ?PrLS, group_concat(distinct ?Remarks;separator=', ') as ?LegRemarkswhere{
?TR pl:TaxonRecordID '11627'.
?TR pl:hasLegislation ?ii.
OPTIONAL{?ii pl:LegislationName ?LegN}.
OPTIONAL{?ii pl:LegislationRead ?LegR}.
OPTIONAL{?ii pl:ProtectionLegalStatus ?PrLS}.
OPTIONAL{?ii pl:Remarks ?Remarks}.} }
UNION {
?TR pl:TaxonRecordID '11627' .
?TR pl:hasDirectThreats ?DiTh .
?DiTh pl:DirectThreatUnstructured ?ThUn. }
UNION {
?TR pl:TaxonRecordID '11627'.
?TR pl:hasHabitats ?Ha.?Ha pl:HabitatUnstructured ?HaUn.}
UNION {
?TR pl:TaxonRecordID '11627'.
?TR pl:hasThreatStatus ?TS .
OPTIONAL{?TS pl:Year ?Year}.
OPTIONAL{?TS pl:Authority ?Authority}.
OPTIONAL{?TS pl:ThreatCategory ?Cat}.
OPTIONAL{?TS pl:ThreatStatusUnstructured ?TSUn}.
OPTIONAL{?TS pl:coverageArea ?covArea}.}
UNION {
?TR pl:TaxonRecordID '11627' .
?TR pl:hasManagementConservation ?MC .
OPTIONAL{?MC dw:ConservationMeasurementUnstructured ?ConMeUn}.
OPTIONAL{?MC dw:HumanAndEnvironmentalRelevanceUnstructured ?HUR}.
?MC pl:Objectives ?Obj.
?MC pl:ManagementType ?ManType.
OPTIONAL{?MC dw:HumanAndEnvironmentalRelevance ?HuER}.
?MC dw:ManagementRemarks ?q.
?MC dw:ManagementPlan ?y.
bind(concat(?q, '. ', ?y) as ?ManRem).
OPTIONAL{?MC dw:ManagementRemarks ?Pln}.
OPTIONAL{?MC dw:Year ?Dt}. }
UNION {
?TR pl:TaxonRecordID '11627' .
?TR pl:hasPopulationBiology ?PoBi .
?PoBi pl:PopulationBiologyUnstructured ?PoBiUn}
UNION {
?TR pl:TaxonRecordID '11627' .
?TR pl:hasRecordMetadata ?RMt .
?RMt pl:hasRevision ?Rev .
?Rev dc:title ?ti.
?Rev dc:source ?so.
}}

 

Run query

 

 

All species located at a geographical point ( -3.6931314467074112, 40.44180608351954)

 

PREFIX plinian:<http://datos.iepnb.es/def/pliniancore#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dwc: <http://rs.tdwg.org/dwc/terms/>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX grid: <http://datos.iepnb.es/def/spatialgrid#>
PREFIX darwin: <http://rs.tdwg.org/dwc/terms/>
PREFIX skos: <http://datos.iepnb.es/resource/Concept/>
select DISTINCT
?TaxonRecordId as ?Taxon ?ScientificName ?SpecificEpithet ?HigherClassification ?CodEunis
from <http://datos.iepnb.es/graph/spatialgrid> from <http://datos.iepnb.es/graph/pliniancore>
where {
?Location plinian:hasCell ?cuadricula .
?Location plinian:isLocationOf ?TaxonRecord .
?TaxonRecord plinian:hasHierarchy ?b .
?TaxonRecord plinian:TaxonRecordID ?TaxonRecordId.
?b darwin:scientificName ?ScientificName .
OPTIONAL{?TaxonRecord plinian:CodeEUNIS ?CodEunis}.
OPTIONAL{?b darwin:higherClassification ?HigherClassification} .
OPTIONAL{?b darwin:specificEpithet ?SpecificEpithet } .
?cuadricula geo:asWKT ?WKT .
FILTER (bif:st_intersects(bif:st_geomfromtext(STR(?WKT)),bif:st_point(-3.6931314467074112, 40.44180608351954),0))
}
order by ?TaxonRecord

 

Run query

 

 

Get the legislation about the species 'Canis lupus' through a federated query between the 'eidos' endpoint and the 'eunis' endpoint

 

PREFIX pl:<https://datos.iepnb.es/def/sector-publico/medio-ambiente/pliniancore#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX e: <http://eunis.eea.europa.eu/rdf/species-schema.rdf#>
PREFIX t: <http://eunis.eea.europa.eu/rdf/taxonomies-schema.rdf#>
PREFIX s: <http://eunis.eea.europa.eu/rdf/schema.rdf#>
select DISTINCT ?EidosLegislationName ?EunisSp ?EunisLegalReferenceComment ?LegalReferenceAnnex STR(?LegalReferencePriority) as ?LegalReferencePriority
where { {
?TaxonRecord pl:TaxonRecordID '11627'.
?TaxonRecord pl:CodeEUNIS ?CodEunisEidos.
?TaxonRecord pl:hasLegislation ?EidosLegislation.
?EidosLegislation pl:LegislationName ?EidosLegislationName.}
UNION {
?TaxonRecord pl:TaxonRecordID '11627'.
?TaxonRecord pl:CodeEUNIS ?CodEunisEidos.
bind(xsd:int(?CodEunisEidos) as ?CodEunis).
SERVICE <http://semantic.eea.europa.eu/sparql> {
SELECT * WHERE {
?EunisSp e:speciesCode ?CodEunis .
OPTIONAL{?EunisSp e:hasLegalReference ?LegalReference.
OPTIONAL{?LegalReference s:comment ?EunisLegalReferenceComment}.
OPTIONAL{?LegalReference s:annex ?LegalReferenceAnnex}.
OPTIONAL{?LegalReference s:priority ?LegalReferencePriority}}}}}}

Ejecutar Consulta

Run query   

 

 

Get the EIDOS species and the elements of the geographic data catalog (BTN100) located at a geographical point (-4.193481042981146, 41.38505189939636) through a query federated to the Crossnature and IGN endpoints

 

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX plinian:<http://datos.iepnb.es/def/pliniancore#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX malla: <http://datos.iepnb.es/def/spatialgrid#>
PREFIX res: <http://datos.iepnb.es/resource/Concept/>
PREFIX dc: <http://purl.org/dc/terms/>
PREFIX darwin: <http://rs.tdwg.org/dwc/terms/>
PREFIX btn100: <https://datos.ign.es/def/btn100#>
PREFIX esadm: <http://vocab.linkeddata.es/datosabiertos/def/sector-publico/territorio#>
select DISTINCT * where {{{
select DISTINCT ?EidosTaxonRecordId ?EidosScientificName ?EidosCodEunis
where {
?Location plinian:hasCell ?cuadricula .
?Location plinian:isLocationOf ?TaxonRecord .
?TaxonRecord plinian:hasHierarchy ?b .
?TaxonRecord plinian:TaxonRecordID ?EidosTaxonRecordId.
?b darwin:scientificName ?EidosScientificName .
OPTIONAL{
?TaxonRecord plinian:CodeEUNIS ?EidosCodEunis}.
{select DISTINCT ?cuadricula ?CodCelda where {
?cuadricula rdf:type malla:cell .
?cuadricula malla:hasCoordinateSystem res:ETRS89_ETRS_LAEA .
?cuadricula geo:asWKT ?WKT .
?cuadricula malla:cod ?CodCelda .
FILTER (bif:st_intersects(bif:st_geomfromtext(STR(?WKT)),bif:st_point(-4.193481042981146, 41.38505189939636),0))}
limit 1}}order by ?EidosScientificName}}
UNION {{
SERVICE <https://datos.ign.es/sparql> {
select * where {{
select DISTINCT ?IgnName where {
?Ign geo:hasGeometry ?geom.
?Ign dc:title ?IgnName .
?geom geo:asWKT ?WKT2 .
FILTER (bif:st_intersects(?WKT2, bif:st_point(-4.193481042981146, 41.38505189939636)))}limit 1000}
UNION {
select DISTINCT ?IgnName ?IgnAltitudOrtometrica ?IgnCota
where {
?Ign geo:hasGeometry ?geom.
?geom rdf:type <http://www.opengis.net/ont/sf#Point>.
?Ign dc:title ?IgnName .
OPTIONAL{
?Ign btn100:altitudOrtometrica ?IgnAltitudOrtometrica} .
OPTIONAL{?Ign btn100:cota ?IgnCota} .
?geom geo:asWKT ?WKT2 .
FILTER (bif:GeometryType (?WKT2) = 'POINT') .
FILTER (bif:st_distance(?WKT2,bif:st_point(-4.193481042981146, 41.38505189939636))<5) .}
limit 1000}}}}}} limit 1000

 

Run query

Scroll hacia arriba